options nocenter;
data a1; 
   infile 'U:\.www\datasets512\Ch07ta01.dat';
   input skinfold thigh midarm fat;
*proc print data=a1; 
run;

*Fit model and it appears set of variables are helpful but 
  each individual parameter is not helpful;
proc reg data=a1; 
   model fat=skinfold thigh midarm;
run;

*How to look at both Type I and Type II SS;
proc reg data=a1; 
   model fat=skinfold thigh midarm /ss1 ss2;
run;

*Fit just one variable and it is helpful.  Why does this 
  happen;
proc reg data=a1; 
   model fat=skinfold;
run;

*Test if the other two variables are helpful after skinfold 
  is fit;
proc reg data=a1; 
   model fat=skinfold thigh midarm;
   thimid: test thigh, midarm;
run;

*How to compute the partial correlation (SAS gives squared 
  correlation);
proc reg data=a1; 
   model fat=skinfold thigh midarm / pcorr2;
run;

*Using standardized variables;
proc reg data=a1; 
   model fat=skinfold thigh midarm / stb;
run;

*Getting correlation coefficients between each variable
   in the model.  Also looking at correlation among several
   variables;
proc reg data=a1 corr; 
   model fat=skinfold thigh midarm;
   model midarm = skinfold thigh;
run;