*NKNW1020.sas, one-way analysis of covariance 
   using data from Table 25.1;
options nocenter;
data a1; infile 'U:\.www\datasets512\CH25TA01.DAT';
   input cases last treat store;
proc print data=a1; run;
title1 'Plot of the data';
symbol1 v='1' i=none c=black;
symbol2 v='2' i=none c=black;
symbol3 v='3' i=none c=black;
proc gplot data=a1; 
   plot cases*last=treat/frame;
run;
title1 'Plot of the data with lines';
symbol1 v='1' i=rl c=black;
symbol2 v='2' i=rl c=black;
symbol3 v='3' i=rl c=black;
proc gplot data=a1; 
   plot cases*last=treat/frame;
run;
proc glm data=a1; 
   class treat;
   model cases=last treat;
run;
proc glm data=a1; 
   class treat;
   model cases=last treat/solution;
run;
proc glm data=a1; 
   class treat;
   model cases=last treat;
   lsmeans treat/stderr tdiff pdiff cl;
run;
title1 'Plot of the data with the model';
proc glm data=a1; 
   class treat;
   model cases=last treat;
   output out=a2 p=pred;
data a3; set a2; 
   drop cases pred;
   if treat eq 1 then do 
     cases1=cases; 
     pred1=pred;
     output; end;
   if treat eq 2 then do 
     cases2=cases; 
     pred2=pred;
     output; end;
  if treat eq 3 then do 
     cases3=cases; 
     pred3=pred;
     output; end;
proc print data=a3; 
run;
symbol1 v='1' i=none c=black;
symbol2 v='2' i=none c=black;
symbol3 v='3' i=none c=black;
symbol4 v=none i=rl c=black;
symbol5 v=none i=rl c=black;
symbol6 v=none i=rl c=black;
proc gplot data=a3; 
   plot (cases1 cases2  cases3 pred1 pred2 pred3)*last/frame overlay;
run;
title1 'Check for equal slopes';
proc glm data=a1; 
   class treat;
   model cases=last treat last*treat;
run;