options nocenter;
goptions reset=global colors=(none);

data problem81;
 infile 'i:\.www\datasets502\EX0502.DAT' firstobs=2 dlm='09'x;
 input person sbp quet age smk;

/* Compute frequency table for smk */
proc freq;
 tables smk;
run;

/* Generate summary statistics and histograms for sbp, age, quet */
proc univariate;
 var sbp quet age;
 histogram sbp quet age / kernel;
run;

/* Generate scatterplots for several variable combinations*/
symbol1 v=circle i=none;
proc gplot;
 plot sbp*quet sbp*age quet*age;
run;

/* Estimate regression lines */
proc reg;
 model sbp quet = age;
 model sbp = quet;
 model sbp = smk;
run;

/* Generate side to side boxplots (smk=0 and 1) for sbp, age, and quet */
proc sort; by smk;
proc boxplot;
 plot (sbp quet age)*smk / pctldef=4;
run;

/* Generate scattterplots with different regression lines for smk=0 and 1 */
symbol1 v=circle i=rl;
symbol2 v=plus i=rl line=2;
proc gplot;
 plot sbp*quet=smk sbp*age=smk;
run;

/* Create new independent variables to investigate */
data problem81;
 set problem81;
 quet_smk = quet*smk;
 quet_age = quet*age;

/* Investigate different models */
proc reg;
 model sbp = quet age smk quet_smk quet_age;
 plot r.*p. /nostat legend=none;
 plot r.*nqq. / nostat;
run;
 delete quet_smk;
 print;
run;
 delete quet_age;
 print;
run;
delete quet;
 print;
run;